# Automatic chat messages on your Minecraft server (no plugins)

> How to set up automatic announcements in your Minecraft server chat every few minutes, without plugins: a data pack with /schedule or a scheduled task.

Original page: https://napnodes.com/en/guides/minecraft-server-auto-messages · Updated: 2026-11-13

The link to your Discord, the rules, Saturday's event: if you repeat it by hand you forget, and if you don't, nobody reads it. An automatic chat message every few minutes fixes that, and you don't need a plugin. Here are two ways: a four-file data pack that works on Paper and vanilla, and the panel's schedules for hourly messages or a fixed day and time.

## Which way suits you

If you want several messages taking turns every 10 or 15 minutes, with colours and links that open with a click, go with the data pack. It works the same on Paper and vanilla, on the free server and on a paid one, and it keeps working if you ever change host.

If one message an hour is enough, or one at a fixed time (“Event at spawn at 22:00” on Friday), use the [panel's schedules](https://napnodes.com/en/guides/scheduled-tasks-auto-restart-server): they take a minute to set up and you don't touch any files.

There are announcement plugins, but you don't need one for this, and one more plugin is one more thing to update with every Minecraft version.

## The data pack's four files

A data pack is a folder with a `pack.mcmeta` and some functions: lists of commands the server runs. The `load` function runs at startup and on every reload (`minecraft:reload`), and schedules the `siguiente` (“next”) function. That one shows a message and schedules itself again, so it repeats by itself while the server is on.

The messages take turns with a scoreboard that counts which one is next: 1, 2, 3 and back to the start. Swap the texts for yours and, if you want more messages, add more lines and raise the `4..` to the number of messages plus one.

The `pack.mcmeta` below is the one for 26.3. If your server runs another version, get yours with the [pack.mcmeta generator](https://napnodes.com/en/tools/minecraft-pack-mcmeta-generator): with a number that isn't your version's, the data pack won't turn on.

File: `anuncios/pack.mcmeta`

```
{
  "pack": {
    "description": "Automatic messages",
    "min_format": 121,
    "max_format": 121
  }
}
```

File: `anuncios/data/minecraft/tags/function/load.json`

```json
{
  "values": ["anuncios:load"]
}
```

File: `anuncios/data/anuncios/function/load.mcfunction`

```mcfunction
# At startup and on every minecraft:reload
scoreboard objectives add anuncios dummy
schedule function anuncios:siguiente 600s replace
```

File: `anuncios/data/anuncios/function/siguiente.mcfunction`

```mcfunction
# Every 600 seconds (10 minutes), the next message
scoreboard players add #turno anuncios 1
execute if score #turno anuncios matches 4.. run scoreboard players set #turno anuncios 1
execute if score #turno anuncios matches 1 run tellraw @a {"text":"Not on our Discord yet? Click here","color":"aqua","click_event":{"action":"open_url","url":"https://discord.gg/YOUR-CODE"}}
execute if score #turno anuncios matches 2 run tellraw @a {"text":"Remember: no breaking other people's builds. The rules are at spawn.","color":"gold"}
execute if score #turno anuncios matches 3 run tellraw @a {"text":"Saturday at 22:00, event at spawn. Bring your friends!","color":"green"}
schedule function anuncios:siguiente 600s replace
```

## How often: seconds, not minutes

The `schedule` time only understands three units: `t` (ticks, 20 per second), `s` (seconds) and `d` (in-game days, 20 real minutes each). There are no minutes: `10m` is an error and the data pack repeats nothing. For 10 minutes, `600s`; for 15, `900s`; for 30, `1800s`. Change it in both functions.

The `replace` at the end means there are never two loops running at once, even if you reload several times in a row.

Don't overdo it: a message every 10 or 15 minutes gets read; one every minute floods the chat and people stop looking. Three or four messages taking turns are plenty.

## Uploading it to your server

1. **Make the folder on your PC**: A folder called `anuncios` with the four files at their paths, as above. Save them as UTF-8 (the default in Notepad on Windows 11) so accents and special characters come out right.
2. **Zip it the right way**: Zip what's INSIDE `anuncios` (the `pack.mcmeta` and the `data` folder), not the folder itself: when you open the .zip you should see `pack.mcmeta` straight away.
3. **Upload it to datapacks**: In the panel, “Files” → the world folder (`world`, unless you changed it) → `datapacks`, and “Upload” the .zip. If you'd rather not use your PC, you can create the folders right there with “Create Directory” and each file with “New File”.
4. **Load it and test it**: Restart the server or type `minecraft:reload` in “Console” (on Paper, plain `reload` also reloads plugins, which can cause them trouble). `datapack list` should show it as enabled. To see the first message without waiting, `function anuncios:siguiente`.

## Stopping, changing or removing it

To stop it until the next restart, `schedule clear anuncios:siguiente`. To remove it for good, delete the .zip from `datapacks` and restart.

To change a message, edit `siguiente.mcfunction` and type `minecraft:reload`. Colours, bold and links are quicker to put together with the [/tellraw generator](https://napnodes.com/en/tools/minecraft-tellraw-generator): copy what comes after `tellraw @a` and paste it on its line. What you can put in each message is covered in the [/title and /tellraw guide](https://napnodes.com/en/guides/minecraft-title-tellraw-commands).

If the server is empty, Minecraft pauses the world after the seconds set in “Pause the empty world (seconds)” (in “Settings”), and the message timer with it: it carries on where it was when someone joins again. No message is lost and nobody reads messages in an empty chat.

## With the panel's schedules

In “Advanced settings” → “Schedules”, pick “Send a message to players” and type the text: it shows in chat as `[Server]` followed by your message. Under “When”, “Every few hours” (every 1, 2, 3, 4, 6, 8 or 12), “Every day” at a set time or “Some days of the week”. Times are Spain time (Madrid).

For a message with colour or a link, pick “Run a console command” and paste the `tellraw @a {…}` without the slash. The field takes up to 200 characters: for longer messages, use the data pack.

Several different messages through the day are several schedules, each at its own time. And “Run it now” sends it straight away, so you can see how it looks.

## And in Project Zomboid or Hytale

“Send a message to players” is also there for Project Zomboid and Hytale, with the same “When” options. Valheim has no console command for messages, so that option doesn't show up.

## Questions

### How do I set up automatic messages on my Minecraft server without plugins?

With a four-file data pack: a function that shows the message with tellraw and schedules itself again every 600 seconds. It works on Paper and vanilla.

### Why doesn't schedule work with minutes?

Because it only accepts ticks (t), seconds (s) and in-game days (d). For 10 minutes, type 600s.

### Can I add a Discord link that opens with one click?

Yes: in the tellraw, click_event with the open_url action and the address. It must start with https:// or http://.

### Can I schedule a message in the NapNodes panel?

Yes, in “Advanced settings” → “Schedules” → “Send a message to players”, every few hours, every day or on some days of the week.

### How do I stop the automatic messages?

Until the next restart, schedule clear with the function's name. For good, delete the data pack from the datapacks folder and restart.

---

NapNodes gives you a free Minecraft server, no card and no end date: it isn't always on (it switches itself off after an hour with nobody on, and you start it again with one click). How it works: https://napnodes.com/en/free. Paid plans, always on and with no commitment: https://napnodes.com/en/pricing.
